Как из АКЦЕССА закрыть вордовский файл без сохранения?

smi
Дата: 28.09.2005 01:09:10
Добрый вечер всем.
Пытаюсь произвести слияния Акцесса с Вордом. Для этой цели воспользовался кодом подсмотренным у Гетца. Вот он:

Private Const conTemplate As String = "Платежка.dot"
Private Const conQuery As String = "qryПлатежка"

Private Function FixPath(strPath As String) As String
    If Right(strPath, 1) = "\" Then
        FixPath = strPath
    Else
        FixPath = strPath & "\"
    End If
End Function

Public Sub Кнопка_Click()
Dim strPath As String
Dim strDataSource As String
Dim doc As Word.Document
Dim wrdApp As Word.Application
        
    strPath = FixPath(CurrentProject.Path)
    strDataSource = strPath & conQuery & ".doc"
    Kill strDataSource
    
    DoCmd.OutputTo acOutputQuery, conQuery, _
     acFormatRTF, strDataSource, False

    Set wrdApp = New Word.Application
    Set doc = wrdApp.Documents.Add(strPath & conTemplate)
        
    With doc.MailMerge
        .OpenDataSource Name:=strDataSource
        .Destination = wdSendToNewDocument
        .SuppressBlankLines = True
        With .DataSource
            .FirstRecord = wdDefaultFirstRecord
            .LastRecord = wdDefaultLastRecord
        End With
        If .State = wdMainAndDataSource Then
            .Execute
        End If
    End With
    
    wrdApp.Visible = True
End Sub
В результате выполнения процедуры создаются и открываются два вордовских файла. Первый – собственно сам итоговый результат слияния. И второй, совершенно мне не нужный служебный файл, созданный акцессом на основе шаблона *.dot. Так вот, хочу также программно, в продолжение кода его создавшего, этот служебный вордовский файл - закрыть. Он не имеет имени. Если закрывать его руками хочет сохранения. Как это сделать?
Заранее спасибо

Если кому интересин пример от Гетца может посмотреть здесь
1
Дата: 28.09.2005 08:22:18
doc.Close False
Владимир Саныч
Дата: 28.09.2005 08:34:08
smi
Как из АКЦЕССА закрыть вордовский файл без сохранения?

Это ведь вопрос про методы библиотеки Word. Поэтому я и перенес предыдущий топик в другой форум. И там, кстати, уже ответили:

http://sql.ru/forum/actualthread.aspx?tid=220601
smi
Дата: 28.09.2005 09:36:51
1
doc.Close False

спасибо :-)