Как перебрать программно все TLabel в групбоксе?

Есть GroupBox типа TcxGroupBox. На ней несколько TLabel.
Задача стоит перебрать все лейблы и выбранную пометить ярким цветом, остальные серым.
Делаю так:

procedure HighlightStateView(AGroupBox: TcxGroupBox; ALabel: TLabel);
var
  i: integer;
begin
  for i := 0 to AGroupBox.ComponentCount - 1 do
    begin
      if (AGroupBox.Components[i] is TLabel) then
        begin
          if ((AGroupBox.Components[i] as TLabel) = ALabel) then
            DisplayLbState((AGroupBox.Components[i] as TLabel), 2) // Отображает ярким цветом
          else
            DisplayLbState((AGroupBox.Components[i] as TLabel), 1) // Отображает серым цветом
        end;
    end;
end;

Но при отладке получается, что AGroupBox.ComponentCount равно нулю.

ControlCount

и соответственно не Components[i], а Controls[i]

DimaBr
ControlCount

Спасибо! Так заработало:

procedure HighlightStateView(AGroupBox: TcxGroupBox; ALabel: TLabel);
var
  i: integer;
begin
  for i := 0 to AGroupBox.ControlCount - 1 do
    begin
      if (AGroupBox.Controls[i] is TLabel) then
        begin
          if ((AGroupBox.Controls[i] as TLabel) = ALabel) then
            DisplayLbState((AGroupBox.Controls[i] as TLabel), 2)
          else
            DisplayLbState((AGroupBox.Controls[i] as TLabel), 1)
        end;
    end;
end;

Чем же Components от Controls отличается?

svnvlad

DimaBr ControlCount Спасибо! Так заработало: procedure HighlightStateView(AGroupBox: TcxGroupBox; ALabel: TLabel); var i: integer; begin for i := 0 to AGroupBox.ControlCount - 1 do begin if (AGroupBox.Controls[i] is TLabel) then begin if ((AGroupBox.Controls[i] as TLabel) = ALabel) then DisplayLbState((AGroupBox.Controls[i] as TLabel), 2) else DisplayLbState((AGroupBox.Controls[i] as TLabel), 1) end; end; end; Чем же Components от Controls отличается?

Не только лишь все компоненты контролы.

svnvlad
Чем же Components от Controls отличается?

Буквами

svnvlad
Чем же Components от Controls отличается?

Есть два понятия: владелец (owner) и родитель (parent). Владелец компонента, когда вызывают его деструктор, удалит и все компоненты, которыми владеет. Владелец (owner) всех компонентов на форме - форма.
Родитель - это то, на чем визуально расположен элемент управления.
Свойство TComponent.Components перечисляет все компоненты, которыми владеет данный компонент. Свойство TWinControl.Controls перечисляет все элементы управления, которые являются детьми (child controls) по отношению к данному оконному элементу управления.
Ваш GroupBox является родителем (parent) для лейблов, но не владельцем (owner). Владелец - форма, на которой всё это. Соответственно, лейблы перечислены в свойстве Controls групбокса и в свойстве Components формы.

s62
Свойство TComponent.Components перечисляет все компоненты, которыми владеет данный компонент. Свойство TWinControl.Controls перечисляет все элементы управления, которые являются детьми (child controls) по отношению к данному оконному элементу управления.

наконец-то, и я узнал :)

svnvlad
Задача стоит перебрать все лейблы

можно использовать InheritForm

if AGroupBox.Controls[i].InheritForm(TLabel) then
...

А так будет еще лучше

procedure HighlightStateView(AGroupBox: TcxGroupBox; ALabel: TLabel);
var
  i: integer;
begin
  for i := 0 to AGroupBox.ControlCount - 1 do
    begin
      if AGroupBox.Controls[i] is TLabel then
        begin
          if AGroupBox.Controls[i] = ALabel then
            DisplayLbState(TLabel(AGroupBox.Controls[i]), 2)
          else
            DisplayLbState(TLabel(AGroupBox.Controls[i]), 1)
        end;
    end;
end;